program Longest;
  var
    n,               {количество членов
                      последовательности}
    p,               {номер ее  текущего члена}
    Place,           {номер модифицируемой
                      строки }
    MaxLine : integer;{номер последней строки}
     {исходная последовательность}
    NumberString : array[1..50] of integer;
     {модифицируемоя таблица}
    Tab : array[1..50,1..50] of integer;
 f1,f2:text;
 procedure InData;
   var
     i : integer;
   begin
     readln(f1,n);
     for i:=1 to n do
       begin
         read(f1,NumberString[i]);
       end;
   end;
 procedure OutResult;
   var i : 1..100;
   begin
     for i:=1 to MaxLine-1 do
       write(f2, Tab[MaxLine,i],' ');
       writeln(f2, Tab[MaxLine,maxline]);
   end;
 procedure DownString (Place : integer);
   var
     i: integer;
   begin
     if Place>1
       then
         for i:=1 to (Place-1) do
           Tab[Place,i] := Tab[Place-1,i];
   end;
 function SearchGreater (x : Integer; var k :
                        integer) : boolean;
   var
  Founded: boolean;
  begin
    k:=0; Founded:=false;
    while(k<MaxLine) and (not Founded) do
      begin
        k:=k+1;
        Founded:=x<Tab[k,k]
      end;
    SearchGreater:=Founded;
  end;
begin
  assign(f1,'longest.dat');
  reset(f1);
  assign(f2,'longest.sol');
  rewrite(f2);

  InData;
  Tab[1,1]:=NumberString[1];
  p:=1; MaxLine:=1;
  while p<n do
    begin
      p:=p+1;
      if SearchGreater(NumberString[p], Place)
        then
          begin
            DownString(Place);
            Tab[Place,Place]:=NumberString[p];
          end
        else
          begin
           MaxLine:=MaxLine+1;
              Tab[MaxLine,MaxLine]:=NumberString[p];
           DownString(MaxLine);
          end;
    end;
  OutResult;
  close(f1);
  close(f2);
end.