Глава 7. Рекурсия

     7.1. Примеры рекурсивных программ.

При  анализе  рекурсивной  программы  возникает, как обычно, два
вопроса:

        (а) почему программа заканчивает работу?
        (б) почему она работает правильно, если заканчивает
            работу?

     Для (б) достаточно проверить, что  (содержащая  рекурсивный
вызов) программа работает правильно, предположив, что вызываемая
ею  одноименная  программа  работает  правильно. В самом деле, в
этом случае в цепочке рекурсивно вызываемых программ  все  прог-
раммы работают правильно (убеждаемся в этом, идя от конца цепоч-
ки к началу).
     Чтобы  доказать  (а), обычно проверяют, что с каждым рекур-
сивным вызовом значение какого-то параметра уменьшается,  и  это
не может продолжаться бесконечно.

     7.1.1. Написать рекурсивную процедуру вычисления факториала
целого  положительного  числа  n  (т.е. произведения чисел 1..n,
обозначаемого n!).

     Решение. Используем равенства 1!=1, n!= (n-1)!*n.

        procedure factorial (n: integer; var fact: integer);
        | {положить fact равным факториалу числа y}
        begin
        | if n=1 then begin
        | | fact:=1;
        | end else begin {n>1}
        | | factorial (n-1, fact);
        | | fact:= fact*n;
        | end;
        end;

С использованием процедур-функций можно написать так:

        function factorial (n: integer): integer;
        begin
        | if n=1 then begin
        | | factorial:=1;
        | end else begin {n>1}
        | | factorial:=  factorial (n-1)*n;
        | end;
        end;

Обратите внимание на некоторую двойственность использования име-
ни factorial внутри описания функции: оно обозначает  как  пере-
менную,  так и вызываемую рекурсивно функцию. К счастью, в нашем
случае они различаются  по  скобкам  после  имени,  но  если  бы
функция  была  без  параметров,  то  дело  было бы плохо. (Стан-
дартная, но трудно находимая ошибка возникает, если автор  пола-
гает, что он использует значение переменной, а компилятор в этом
месте видит рекурсивный вызов.)

    7.1.2.  Обычно  факториал определяют и для нуля, считая, что
0!=1. Измените программы соответственно.

    7.1.3. Напишите рекурсивную программу возведения в целую не-
отрицательную степень.

    7.1.4. То же, если требуется, чтобы глубина рекурсии не пре-
восходила C*log n, где n - степень.

    Решение.

        function power (a,n: integer): integer;
        begin
        | if n = 0 then begin
        | | power:= 1;
        | end else if n mod 2 = 0 then begin
        | | power:= power(a*2, n div 2);
        | end else begin
        | | power:= power(a, n-1)*a;
        | end;
        end;

     7.1.5. Что будет, если изменить  программу,  приведенную  в
решении предыдущей задачи, заменив строку

        power:= power(a*2, n div 2)
на
        power:= power(a, n div 2)* power(a, n div 2)?

     Решение. Программа останется правильной. Однако она  станет
работать  медленнее. Дело в том, что теперь вызов может породить
два вызова (хотя и одинаковых) вместо одного - и  число  вызовов
быстро  растет  с глубиной рекурсии. Программа по-прежнему имеет
логарифмическую глубину рекурсии, но число шагов  работы  стано-
вится линейным вместо логарифмического.
     Этот недостаток можно устранить, написав
        t:= power(a, n div 2);
        power:= t*t;
или воспользовавшись функцией возведения в квадрат (sqr).

     7.1.6. Используя лишь команды write(x) при x=0..9, написать
рекурсивную программу печати десятичной  записи  целого  положи-
тельного числа n.

     Решение.  Здесь  использование  рекурсии  облегчает   жизнь
(проблема  была в том, что цифры легче получать с конца, а печа-
тать надо с начала).

     procedure print (n:integer); {n>0}
     begin
     | if n<10 then begin
     | | write (n);
     | end else begin
     | | print (n div 10);
     | | write (n mod 10);
     | end;
     end;

     7.1.7. Игра "Ханойские башни" состоит в следующем. Есть три
стержня.  На  первый из них надета пирамидка из n колец (большие
кольца снизу, меньшие сверху). Требуется переместить  кольца  на
другой  стержень. Разрешается перекладывать кольца со стержня на
стержень,  но класть большее кольцо поверх меньшего нельзя. Сос-
тавить программу, указывающую требуемые действия.

     Решение.  Напишем  рекурсивную  процедуру   перемещения   i
верхних  колец  с  m-го стержня на n-ый (предполагается, что ос-
тальные кольца больше по размеру и лежат на стержнях без  движе-
ния).

    procedure move(i,m,n: integer);
    | var s: integer;
    begin
    | if i = 1 then begin
    | | writeln ('сделать ход', m, '->', n);
    | end else begin
    | | s:=6-m-n; {s - третий стержень: сумма номеров равна 6}
    | | move (i-1, m, s);
    | | writeln ('сделать ход', m, '->', n);
    | | move (i-1, s, n);
    | end;
    end;

(Сначала  переносится  пирамидка из i-1 колец на третью палочку.
После этого i-ое кольцо освобождается, и его можно перенести ку-
да следует. Остается положить на него пирамидку.)

     7.2. Рекурсивная обработка деревьев

     Двоичным деревом называется картинка вроде

                   o
                    \
                     o   o
                      \ /
                   o   o
                    \ /
                     o

Нижняя вершина называется корнем. Из каждой вершины  могут  идти
две  линии: влево вверх и вправо вверх. Вершины, куда они ведут,
называются левым и правым сыновьями  исходной  вершины.  Вершина
может  иметь двух сыновей, а может иметь только одного сына (ле-
вого или правого). Она может и вовсе не иметь сыновей, и в  этом
случае называется листом.
     Пусть x - какая-то вершина двоичного дерева. Она сама вмес-
те  с сыновьями, внуками, правнуками и т.д. образует поддерево с
корнем в x - "поддерево потомков x".

     В  следующих  задачах  мы  предполагаем, что вершины дерева
пронумерованы целыми положительными числами, причем номера  всех
вершин различны. Мы считаем, что номер корня хранится в перемен-
ной root. Мы считаем, что имеются два массива

        l,r: array [1..N] of integer

и левый и правый сын вершины с номером  i  имеют  соответственно
номера  l[i]  и  r[i].  Если вершина с номером i не имеет левого
(или правого) сына, то l[i] (соответственно r[i]) равно  0.  (По
традиции при записи программ мы используем вместо нуля константу
nil, равную нулю.)

     Здесь N - достаточно большое натуральное число (номера всех
вершин  не  превосходят  N). Отметим, что номер вершины никак не
связан с ее положением в дереве и что не все числа  от  1  до  N
обязаны  быть  номерами вершин (и, следовательно, часть данных в
массивах l и r - это мусор).

    7.2.1. Пусть N=7, root=3, массивы l и r таковы:

         i  |   1  2  3  4  5  6  7
       l[i] |   0  0  1  0  6  0  7
       r[i] |   0  0  5  3  2  0  7

Нарисовать соответствующее дерево.

     Ответ:          6   2
                      \ /
                   1   5
                    \ /
                     3

     7.2.2. Написать программу подсчета числа вершин в дереве.

     Решение. Рассмотрим функцию n(x),  равную  числу  вершин  в
поддереве с корнем в вершине номер x. Считаем, что n(nil)=0 (по-
лагая соответствующее поддерево пустым), и не заботимся о значе-
ниях  nil(s)  для чисел s, не являющихся номерами вершин. Рекур-
сивная программа для s такова:

     function n (x:integer):integer;
     begin
     | if x = nil then begin
     | | n:= 0;
     | end else begin
     | | n:= n(l[x]) + n(r[x]) + 1;
     | end;
     end;

(Число вершин в поддереве над вершиной x равно сумме чисел  вер-
шин  над  ее сыновьями плюс она сама.) Глубина рекурсии конечна,
так  как  с  каждым  шагом  высота  соответствующего   поддерева
уменьшается.

     7.2.3. Написать программу подсчета числа листьев в дереве.

     Ответ.

     function n (x:integer):integer;
     begin
     | if x = nil then begin
     | | n:= 0;
     | end else if (l[x]=nil) and (r[x]=nil) then begin {лист}
     | | n:= 1;
     | end;
     | end else begin
     | | n:= n(l[x]) + n(r[x]);
     | end;
     end;

     7.2.4. Написать программу подсчета  высоты  дерева  (корень
имеет высоту 0, его сыновья - высоту 1, внуки - 2 и т.п.; высота
дерева - это максимум высот его вершин).

     Указание.  Рекурсивно  определяется  функция  f(x) = высота
поддерева с корнем в x.

     7.2.5.  Написать  программу, которая по заданному n считает
число всех вершин высоты n (в заданном дереве).

     Вместо подсчета количества вершин того или иного рода можно
просить напечатать список этих вершин (в том или ином порядке).

     7.2.6. Написать программу, которая печатает (по одному  ра-
зу) все вершины дерева.

     Решение.  Процедура  print_subtree(x)  печатает все вершины
поддерева с корнем в x по одному разу; главная программа  содер-
жит вызов print_subtree(root).

     procedure print_subtree (x:integer);
     begin
     | if x = nil then begin
     | | {ничего не делать}
     | end else begin
     | | writeln (x);
     | | print_subtree (l[x]);
     | | print_subtree (r[x]);
     | end;
     end;

Данная программа печатает сначала корень поддерева, затем подде-
рево над левым сыном, а затем над правым. Три строки в else-час-
ти  могут быть переставлены 6 способами, и каждый из этих спосо-
бов дает свой порядок печати вершин.

     7.3. Порождение комбинаторных объектов, перебор

     Рекурсивные программы являются удобным способом  порождения
комбинаторных объектов заданного вида. Мы решим заново несколько
задач соотвтетсвующей главы.

     7.3.1. Написать программу, которая печатает по одному  разу
все  последовательности  длины n, составленные из чисел 1..k (их
количество равно k в степени n).

     Решение. Программа будет оперировать с массивом  a[1]..a[n]
и числом t. Рекурсивная процедура generate печатает все последо-
вательности, начинающиеся на a[1]..a[t]; после  ее  окончания  t
имеет то же значение, что и в начале:

     procedure generate;
     | var i,j : integer;
     begin
     | if t = n then begin
     | | for i:=1 to n do begin
     | | | write(a[i]);
     | | end;
     | | writeln;
     | end else begin {t < n}
     | | for j:=1 to k do begin
     | | | t:=t+1;
     | | | a[t]:=j;
     | | | generate;
     | | | t:=t-1;
     | | end;
     | end;
     end;

Основная программа теперь состоит из двух операторов:
     t:=0; generate;

     7.3.2. Написать программу, которая печатала бы все переста-
новки чисел 1..n по одному разу.

     Решение. Программа оперирует с массивом a[1]..a[n], в кото-
ром  хранится  перестановка  чисел  1..n.  Рекурсивная процедура
generate в такой ситуации печатает все перестановки, которые  на
первых  t позициях совпадают с перестановкой a; по выходе из нее
переменные t и a имеют те же значения, что и до входа.  Основная
программа такова:

    for i:=1 to n do begin a[i]:=i; end;
    t:=0;
    generate;

вот описание процедуры:

     procedure generate;
     | var i,j : integer;
     begin
     | if t = n then begin
     | | for i:=1 to n do begin
     | | | write(a[i]);
     | | end;
     | | writeln;
     | end else begin {t < n}
     | | for j:=t+1 to n do begin
     | | | поменять местами a[t+1] и a[j]
     | | | t:=t+1;
     | | | generate;
     | | | t:=t-1;
     | | | поменять местами a[t+1] и a[j]
     | | end;
     | end;
     end;

     7.3.3. Напечатать все возрастающие последовательности длины
k, элементами которых являются натуральные  числа  от  1  до  n.
(Предполагается, что k не превосходит n - иначе таких последова-
тельностей не существует.)

     Решение. Программа оперирует с массивом a[1]..a[k] и  целой
переменной  t. Предполагая, что a[1]..a[t] - возрастающая после-
довательность чисел натуральных чисел из отрезка 1..n, рекурсив-
но определенная процедура generate печатает все ее  возрастающие
продолжения длины k.

     procedure generate;
     | var i: integer;
     begin
     | if t = k then begin
     | | печатать a[1]..a[k]
     | end else begin
     | | t:=t+1;
     | | for i:=a[t-1]+1 to t-k+n do begin
     | | | a[t]:=i;
     | | | generate;
     | | end;
     | | t:=t-1;
     | end;
     end;

     Замечание. Цикл for мог бы иметь верхней границей n (вместо
t-k+n). Наш вариант экономит часть работы,  учитывая  тот  факт,
что  предпоследний  (k-1-ый)  член  не  может  превосходить n-1,
k-2-ой член не может превосходить n-2 и т.п.
     Основная программа теперь выглядит так:

        t:=1;
        for j:=1 to 1-k+n do begin
        | a[1]:=j;
        | generate;
        end;

Можно было бы добавить к массиву a слева еще и a[0]=0,  положить
t=0 и ограничиться единственным вызовом процедуры generate.

     7.3.4.  Перечислить все представления положительного целого
числа n в виде суммы последовательности невозрастающих целых по-
ложительных слагаемых.

     Решение.  Программа  оперирует  с  массивом a[1..n] (макси-
мальное число слагаемых равно n) и с целой переменной t. Предпо-
лагая, что a[1],...,a[t] - невозрастающая последовательность це-
лых чисел, сумма которых не превосходит  n,  процедура  generate
печатает  все  представления  требуемого  вида, продолжающие эту
последовательность. Для экономии вычислений сумма  a[1]+...+a[t]
хранится в специальной переменной s.

     procedure generate;
     | var i: integer;
     begin
     | if s = n then begin
     | | печатать последовательность a[1]..a[t]
     | end else begin
     | | for i:=1 to min(a[t], n-s) do begin
     | | | t:=t+1;
     | | | a[t]:=i;
     | | | s:=s+i;
     | | | generate;
     | | | s:=s-i;
     | | | t:=t-1;
     | | end;
     | end;
     end;

Основная программа при этом может быть такой:

     t:=1;
     for j:=1 to n do begin
     | a[1]:=j
     | s:=j;
     | generate;
     end;

     Замечание.  Можно немного сэконмить, вынеся операции увели-
чения и уменьшения t из цикла, а также не возвращая s каждый раз
к исходному значению (а увеличивая его на 1 и возвращая к исход-
ному значению в конце). Кроме того,  добавив  фиктивный  элемент
a[0]=n, можно упростить основную программу:

     t:=0; s:=0; a[0]:=n; generate;

     7.3.5.  Написать  рекурсивную  программу обхода дерева (ис-
пользуя те же команды и проверки, что и в главе про обход  дере-
ва).

     Решение.  Процедура  обработать_над обрабатывает все листья
над текущей вершиной и заканчивает работу в той же вершине,  что
и начала. Вот ее рекурсивное описание:

     procedure обработать_над;
     begin
     | if есть_сверху then begin
     | | вверх_налево;
     | | обработать_над;
     | | while есть_справа do begin
     | | | вправо;
     | | | обработать_над;
     | | end;
     | | вниз;
     | end else begin
     | | обработать;
     | end;
     end;

     7.4. Другие применения рекурсии

     Топологическая сортировка. Представим  себе  n  чиновников,
каждый  из  которых  выдает справки определенного вида. Мы хотим
получить все эти справки,  соблюдая  ограничения,  установленные
чиновниками.  Ограничения состоят в том, что у каждого чиновника
есть список справок, которые нужно собрать  перед  обращением  к
нему.  Дело  безнадежно,  если  схема  зависимостей  имеет  цикл
(справку  A  нельзя получить без B, B без C,..., Y без Z и Z без
A). Предполагая, что такого цикла нет, требуется составить план,
указывающий один из возможных порядков получения справок.

     Изображая чиновников точками, а  зависимости  -  стрелками,
приходим  к такой формулировке. Имеется n точек, пронумерованных
от 1 до n. Из каждой точки ведет несколько (возможно, 0) стрелок
в другие точки. (Такая картинка называется ориентированным  гра-
фом.)  Циклов нет. Требуется расположить вершины графа (точки) в
таком порядке, чтобы конец любой стрелки предшествовал ее  нача-
лу. Эта задача называется топологической сортировкой.

     7.4.1. Доказать, что это всегда возможно.

     Решение.  Из  условия  отсутствия циклов вытекает, что есть
вершина, из которой вообще не выходит стрелок (иначе можно  дви-
гаться  по  стрелкам, пока не зациклимся). Ее будем считать пер-
вой. Выкидывая все стрелки, в нее ведущие, мы  сводим  задачу  к
графу с меньшим числом вершин и продолжаем рассуждение по индук-
ции.

     7.4.2.  Предположим,  что  ориентированный  граф без циклов
хранится в такой форме: для каждого i от 1 до n в num[i] хранит-
ся число выходящих из i стрелок, в adr[i][1],..., adr[i][num[i]]
- номера вершин, куда эти стрелки ведут. Составить (рекурсивный)
алгоритм, который производит топологическую сортировку не  более
чем за C*(n+m) действий, где m - число ребер графа (стрелок).

     Замечание.  Непосредственная  реализация  приведенного выше
доказательства существования не дает требуемой оценки; ее прихо-
дится немного подправить.

     Решение. Наша программа будет  печатать  номера  вершин.  В
массиве  printed: array[1..n] of boolean мы будем хранить сведе-
ния о том, какие вершины напечатаны (и корректировать их  однов-
ременно  с  печатью  вершины).  Будем говорить, что напечатанная
последовательность вершин корректна, если никакая вершина не на-
печатана дважды и для любого номера i, входящего в эту последос-
тельность,  все вершины, в которые ведут стрелки из i, напечата-
ны, и притом до i.

     procedure add (i: 1..n);
     | {дано: напечатанное корректно;}
     | {надо: напечатанное корректно и включает вершину i}
     begin
     | if printed [i] then begin {вершина i уже напечатана}
     | | {ничего делать не надо}
     | end else begin
     | | {напечатанное корректно}
     | | for j:=1 to num[i] do begin
     | | | add(adr[i][j]);
     | | end;
     | | {напечатанное корректно, все вершины, в которые из
     | |  i ведут стрелки, уже напечатаны - так что можно
     | |  печатать i, не нарушая корректности}
     | |  if not printed[i] then begin
     | |  | writeln(i); printed [i]:= TRUE;
     | |  end;
     | end;
     end;

Основная программа:

     for i:=1 to n do begin
     | printed[i]:= FALSE;
     end;
     for i:=1 to n do begin
     | add(i)
     end;

     7.4.3.  В  приведенной  программе можно выбросить проверку,
заменив
          if not printed[i] then begin
          | writeln(i); printed [i]:= TRUE;
          end;
на
          writeln(i); printed [i]:= TRUE;
Почему? Как изменится спецификация процедуры?

     Решение.  Спецификацию можно выбрать такой:
       дано: напеватанное корректно
       надо: напечатанное корректно и включает вершину i;
             все вновь напечатанные вершины доступны из i.

     7.4.4. Где использован тот факт, что граф не имеет циклов?

     Решение.  Мы опустили доказательство конечности глубины ре-
курсии. Для каждой вершины  рассмотрим  ее  "глубину"  -  макси-
мальную длину пути по стрелкам, из нее выходящего.  Условие  от-
сутствия циклов гарантирует, что эта величина конечна. Из верши-
ны  нулевой глубины стрелок не выходит. Глубина конца стрелки по
крайней мере на 1 меньше, чем глубина начала. При работе  проце-
дуры  add(i)  все рекурсивные вызовы add(j) относятся к вершинам
меньшей глубины.

     Связная  компонента  графа.  Неориентированный граф - набор
точек (вершин), некоторые из которых соединены  линиями  (ребра-
ми). Неориентированный граф можно считать частным случаем ориен-
тированного графа, в котором для каждой стрелки есть обратная.
     Связной компонентой вершины i называется множество всех тех
вершин, в которые можно попасть из i, идя по ребрам графа. (Пос-
кольку  граф неориентированный, отношение "j принадлежит связной
компоненте i" является отношением эквивалентности.)

     7.4.5. Дан неориентированный граф (для каждой вершины  ука-
зано  число  соседей  и массив номеров соседей, как в предыдущей
задаче). Составить алгоритм, который по заданному i печатает все
вершины связной компоненты i по одному разу (и только их). Число
действий не должно превосходить C*(общее число вершин и ребер  в
связной компоненте).

     Решение.  Программа  в  процессе работы будет "закрашивать"
некоторые вершины графа. Незакрашенной частью графа будем  назы-
вать то, что останется, если выбросить все закрашенные вершины и
ведущие в них ребра. Процедура add(i) закрашивает связную компо-
ненту  i в незакрашенном графе (и не делает ничего, если вершина
i уже закрашена).

     procedure  add (i:1..n);
     begin
     | if вершина i закрашена then begin
     | | ничего делать не надо
     | end else begin
     | | закрасить i (напечатать и пометить как закрашенную)
     | | для всех j, соседних с i
     | | | add(j);
     | | end;
     | end;
     end;

Докажем, что эта процедура действует правильно (в предположении,
что рекурсивные вызовы работают правильно). В самом деле,  ниче-
го, кроме связной компоненты незакрашенного графа, она закрасить
не  может. Проверим, что вся она будет закрашена. Пусть k - вер-
шина, доступная из вершины  i  по  пути  i-j-...-k,  проходящему
только по незакрашенным вершинам. Будем рассматривать только пу-
ти,  не  возвращающиеся  снова  в i. Из всех таких путей выберем
путь с наименьшим j (в порядке просмотра соседей в цикле в  про-
цедуре).  Тогда  при  рассмотрении предыдущих соседей ни одна из
вершин j-...-k не будет закрашена (иначе  j  не  было  бы  мини-
мальным) и потому k окажется в связной компоненте незакрашенного
графа к моменту вызова add(j). Что и требовалось.
     Чтобы установить конечность глубины рекурсии, заметим,  что
на каждом уровне рекурсии число незакрашенных вершин уменьшается
хотя бы на 1.
     Оценим число действий. Каждая вершина закрашивается не  бо-
лее  одного раза - при первым вызове add(i) с данным i. Все пос-
ледующие вызовы происходят при закрашивании соседей - количество
таких  вызовов  не  больше числа соседей - и сводятся к проверке
того, что вершина i уже закрашена. Первый  же  вызов  состоит  в
просмотре  всех  соседей  и  рекурсивных вызовах add(j) для всех
них. Таким образом, общее число действий, связанных  с  вершиной
i, не превосходит константы, умноженной на число ее соседей. От-
сюда и вытекает требуемая оценка.

     7.4.6.  Решить ту же задачу для ориентированного графа (на-
печатать все вершины, доступные из данной по стрелкам; граф  мо-
жет содержать циклы).

     Ответ.  Годится  по  существу  та же программа (строку "для
всех соседей" надо заменить на  "для  всех  вершин,  куда  ведут
стрелки").

     Быстрая сортировка Хоара. В заключение приведем рекурсивный
алгоритм сортировки массива, который на практике является  одним
из  самых быстрых. Пусть дан массив a[1]..a[n]. Рекурсивная про-
цедура  sort (l,r:integer) сортирует участок массива с индексами
из полуинтервала (l,r] (т.е. a[l+1]..a[r]),  не  затрагивая  ос-
тального массива.

     procedure sort (l,r: integer);
     begin
     | if (l = r) then begin
     | | ничего делать не надо - участок пуст
     | end else begin
     | | выбрать случайное число s в полуинтервале (l,r]
     | | b := a[s]
     | | переставить элементы сортируемого участка так, чтобы
     | |   сначала шли элементы, меньшие b - участок (l,ll]
     | |   затем элементы, равные b        - участок (ll,rr]
     | |   затем элементы, большие b       - участок (rr,r]
     | | sort (l,ll);
     | | sort (rr,r);
     | end;
     end;

Перестановка  элементов  сортируемого  участка рассматривалась в
главе о массивах (это можно сделать за  время,  пропорциональное
длине участка). Конечность глубины рекурсии  гарантируется  тем,
что   длина  сортируемого  участка  на  каждом  уровне  рекурсии
уменьшается хотя бы на 1.

     7.4.7. (Для знакомых с основами теории вероятностей). Дока-
зать, что математическое ожидание числа операций при работе это-
го алгоритма не превосходит C*n*log n, причем константа C не за-
висит от сортируемого массива.

     Указание. Пусть T(n) -  максимум  математического  ожидания
числа  операций для всех входов длины n. Из текста процедуры вы-
текает такое неравенство:

     T(n) <= Cn + 1/n [сумма по всем  k+l=(n-1) чисел T(k)+T(l)]

Первый член соответствует распределению  элементов  на  меньшие,
равные  и большие. Второй член - это среднее математическое ожи-
дание для всех вариантов случайного выбора. (Строго говоря, пос-
кольку среди элементов могут быть равные, в правой части  вместо
T(k) и T(l) должны стоять максимумы T(x) по всем x, не превосхо-
дящим  k или l, но это не мешает дальнейшим рассуждениям.) Далее
индукцией по n нужно доказывать оценку T(n)  <=  C'nlog  n.  При
этом   для   вычисления  среднего  значения  x  log  x  по  всем
x=1,..,n-1 нужно интегрировать x lnx по частям как lnx * d(x*x).
При достаточно большом C' член Cn в правой части  перевешивается
за счет интеграла x*x*d(ln x), и индуктивный шаг проходит.

     7.4.8. Имеется массив из n различных целых чисел a[1]..a[n]
и число k. Требуется найти k-ое по величине число в этом  масси-
ве,  сделав  не более C*n действий, где C - некоторая константа,
не зависящая от k.

     Замечание. Сортировка позволяет очевидным  образом  сделать
это  за  C*n*log(n) действий. Очевидный способ: найти наименьший
элемент, затем найти второй, затем третий,..., k-ый требует  по-
рядка  k*n действий, то есть не годится (константа при n зависит
от k).

      Указание.  Изящный  (хотя  практически  и  бесполезный   -
константы слишком велики) способ сделать это таков:
     А. Разобьем наш массив на n/5 групп, в каждой из которых по
5 элементов. Каждую группу упорядочим.
     Б.  Рассмотрим средние элементы всех групп и перепишем их в
массив из n/5 элементов. С помощью  рекурсивного  вызова  найдем
средний по величине элемент этого массива.
     В.  Сравним этот элемент со всеми элементами исходного мас-
сива: они разделятся на большие его и меньшие его (и один равный
ему). Подсчитав количество тех и других, мы узнаем, в  какой  из
этих  частей  должен находится искомый (k-ый) элемент и каков он
там по порядку.
     Г. Применим рекурсивно наш алгоритм к выбранной части.

     Пусть  T(n)  -  максимально  возможное число действий, если
этот способ применять к массивам из не более чем n элементов  (k
может быть каким угодно). Имеем оценку:
     T(n) <= Cn + T(n/5) + T(примерно 0.7n)
Последнее слагаемое объясняется так: при разбиении на части каж-
дая часть содержит не менее 0.3n элементов. В самом деле, если x
-  средний  из средних, то примерно половина всех средних меньше
x. А если в пятерке средний элемент меньше x, то еще два заведо-
мо меньше x. Тем самым по крайней мере 3/5 от половины элементов
меньше x.
    Теперь  по  индукции можно доказать оценку T(n) <= Cn (реша-
ющую роль при этом играет то обстоятельство, что 1/5 + 0.7 < 1).