Глава 6. Типы данных.

     6.1. Стеки.

     Пусть Т - некоторый тип. Рассмотрим (отсутствующий в паска-
ле)  тип "стек элементов типа Т". Его значениями являются после-
довательности значений типа Т.

     Операции:

Сделать_пустым (var s: стек элементов типа Т).
Добавить (t: T; var s: стек элементов типа Т).
Взять (var t: T; var s: стек элементов типа Т).
Пуст (s: стек элементов типа Т): boolean
Вершина (s: стек элементов типа Т): T

     (Мы пользуемся обозначениями, наполняющими паскаль, хотя  в
паскале типа "стек" нет.) Процедура "Сделать_пустым" делает стек
s  пустым.  Процедура  "Добавить" добавляет t в конец последова-
тельности  s.  Процедура  "Взять"  определена,  если  последова-
тельность  s непуста; она забирает из неё последний элемент, ко-
торый становится значением переменной t. Выражение "Пуст(s)" ис-
тинно, если последовательность s пуста.  Выражение  "Вершина(s)"
определено, если последовательность s непуста, и равно последне-
му элементу последовательности s.
     Мы  покажем,  как моделировать стек в паскале и для чего он
может быть нужен.

     Моделирование ограниченного стека в массиве.

     Будем считать, что количество элементов в стеке не  превос-
ходит  некоторого  числа  n. Тогда стек можно моделировать с по-
мощью двух переменных:
        Содержание: array [1..n] of T;
        Длина: integer;
считая, что в стеке находятся элементы Содержание [1],...,Содер-
жание [длина].

     Чтобы сделать стек пустым, достаточно положить
        Длина := 0

     Добавить элемент t:
         {Длина < n}
         Длина := Длина+1;
         Содержание [Длина] :=t;

     Взять элемент в переменную t:
         t := Содержание [Длина];
         Длина := Длина - 1;

     Стек пуст, если Длина = 0.

     Вершина стека равна Содержание [Длина].

Таким образом, вместо переменной типа стек в программе на паска-
ле можно использовать две переменные Содержание и  Длина.  Можно
также определить тип стек, записав

    const N = ...
    type  stack = record
                    Содержание: array [1..N] of T;
                    Длина: integer;
                  end;

(Мы позволяем себе  использовать  имена  переменных  из  русских
букв,  хотя  обычно  паскаль  этого не любит.) После этого могут
быть - в соответствии с правилами паскаля  -  описаны  процедуры
работы со стеком. Например, можно написать

        procedure Добавить (t: T; var s: stack);
        begin
        | {s.Длина , N}
        | s.Длина := s.Длина + 1;
        | s.Содержание [s.Длина] := t;
        end;

     Использование стека.

     Будем рассматривать последовательности открывающихся и зак-
рывающихся круглых и квадратных скобок ( ) [ ]. Среди всех таких
последовательностей  выделим правильные - те, которые могут быть
получены по таким правилам:

        1) пустая последовательность правильна.
        2) если А и В правильны, то и АВ правильна.
        3) если А правильна, то [A] и (A) правильны.

     Пример. Последовательности (), [[]], [()[]()][]  правильны,
а последовательности ], )(, (], ([)] - нет.

     6.1.1.  Проверить правильность последовательности за время,
не превосходящее константы, умноженной на её длину.  Предполага-
ется, что члены последовательности закодированы числами:
         (   1
         [   2
         )  -1
         ]  -2

     Решение. Пусть a[1]..a[n] - проверяемая последовательность.
Рассмотрим  стек,  элементами  которого  являются  открывающиеся
круглые и квадратные скобки (т. е. 1 и 2).
     Вначале стек делаем пустым. Далее просматриваем члены  пос-
ледовательности  слева  направо.  Встретив  открывающуюся скобку
(круглую или квадратную), помещаем её в стек. Встретив  закрыва-
ющуюся,  проверяем, что вершина в стеке - парная ей скобка; если
это не так, то можно утверждать, что  последовательность  непра-
вильна,  если  скобка  парная, то заберем её (вершину) из стека.
Последовательность правильна,  если  в  конце  стек  оказывается
пуст.
        Сделать_Пустым (s);
        i := 0; Обнаружена_Ошибка := false;
        {прочитано i символов последовательности}
        while (i < n) and not Обнаружена_Ошибка do begin
        | i := i + 1;
        | if (a[i] = 1) or (a[i] = 2) then begin
        | | Добавить (a[i], s);
        | end else begin  {a[i] равно -1 или -2}
        | | if Пуст (s) then begin
        | | | Обнаружена_Ошибка := true;
        | | end else begin
        | | | Взять (t, s);
        | | | Обнаружена ошибка := (t <> - a[i]);
        | | end;
        | end;
        end;
        Правильно := (not Обнаружена_Ошибка) and Пуст (s);

       Убедимся  в  правильности  программы. (1) Если последова-
тельность построена по правилам, то программа даст  ответ  "да".
Это легко доказать индукцией по построению правильной последова-
тельности.  Надо проверить для пустой, для последовательности AB
в предположении, что для A и B уже проверено - и для  последова-
тельностей [A] и (A) - в предположении, что для A уже проверено.
Для  пустой  очевидно.  Для AB действия программы происходят как
для A и кончаются с пустым стеком; затем все происходит как  для
B.  Для  [A]  сначала  помещается  в стек открывающая квадратная
скобка и затем все идет как для A - с той разницей, что в глуби-
не стека лежит лишняя скобка. По  окончании  A  стек  становится
пустым  - если не считать этой скобки - а затем и совсем пустым.
Аналогично для (A).
     (2) Покажем, что если программа завершает работу с  ответом
"да",  то последовательность правильная. Рассуждаем индукцией по
длине последовательности. Проследим за состоянием стека  в  про-
цессе работы программы. Если он в некоторый промежуточный момент
пуст, то последовательность разбивается на две части, для каждой
из  которых  программа дает ответ "да"; остается воспользоваться
предположением индукции и определением правильности. Пусть  стек
все  время  непуст.  Это значит, что положенная в него на первом
шаге скобка будет вынута на последнем шаге. Тем самым, первый  и
последний символы последовательности - это парные скобки, и пос-
ледовательность имеет вид (A) или [A], а работа программы (кроме
первого  и  последнего  шагов) отличается от ее работы на A лишь
наличием лишней скобки на дне стека (раз ее не вынимают, она ни-
как не влияет на работу программы). Снова ссылаемся на предполо-
жение индукции и определение правильности.

     6.1.2. Как упростится программа, если известно, что в  пос-
ледовательности могут быть только круглые скобки?

     Решение.  В этом случае от стека остается лишь его длина, и
мы фактически приходим к такому утверждению:  последовательность
круглых скобок правильна тогда и только тогда, когда в любом на-
чальном  ее  отрезке  число  закрывающихся скобок не превосходит
числа открывающихся, а для  всей  последовательности  эти  числа
равны.

     6.1.3. Реализовать с помощью одного массива два стека, сум-
марное количество элементов в которых ограничено длиной массива;
все  действия со стеками должны выполняться за время, ограничен-
ное константой, не зависящей от длины стеков.

     Решение. Стеки должны расти с концов массива навстречу друг
другу: первый должен занимать места
        Содержание[1] ... Содержание[Длина1],
а второй  -
        Содержание[n] ... Содержание[n - Длина2 + 1]
(вершины обоих стеков записаны последними).

     6.1.4. Реализовать k стеков с элементами типа T, общее  ко-
личество  элементов в которых не превосходит n, с использованием
массивов суммарной длины C*(n+k), затрачивая на каждое  действие
со  стеками (кроме начальных действий, делающих все стеки пусты-
ми) время, ограниченное некоторой константой.

     Решение. Применяемый метод называется "ссылочной реализаци-
ей". Он использует три массива:
        Содержание: array [1..n] of T;
        Следующий: array [1..n] of 0..n;
        Вершина: array [1..k] of 0..n.
     Массив Содержание будем изображать как n ячеек  с  номерами
1..n,  каждая  из которых содержит элемент типа T. Массив Следу-
ющий изобразим в виде стрелок, проведя стрелку из i  в  j,  если
Следующий[i] = j. (Если Следующий[i] = 0, стрелок из i не прово-
дим.) Содержимое s-го стека (s из 1..k)  хранится  так:  вершина
равна Содержание[Вершина[s]], остальные элементы s-го стека мож-
но  найти,  идя  по стрелкам - до тех пор, пока они не кончатся.
При этом (s-ый стек пуст) <=> Вершина[s] = 0.
     Стрелочные траектории, выходящие из Вершина[1], ..., Верши-
на[k] (из тех, которые не равны 0) не должны пересекаться. Поми-
мо них, нам понадобится еще одна стрелочная траектория, содержа-
щая все неиспользуемые в данный момент ячейки. Ее начало мы  бу-
дем  хранить в переменной Свободная (равенство Свободная = 0 оз-
начает, что пустого места не осталось). Вот что получается:

 n=8 | a | p | q | d | s | t | v | w |

 k=2  |  |  |            Свободная

Содержание = <a,p,q,d,s,t,v,w>, Следующий  =  <3,0,6,0,0,2,5,4>
Вершина = <1, 7>, Свободная = 8
Стеки: 1-ый: p t q a (a-вершина); 2-ой: s v (v-вершина).

  procedure Начать_работу; {Делает все стеки пустыми}
  | var i: integer;
  begin
  | for i := 1 to k do begin
  | | Вершина [i]:=0;
  | end;
  | for i := 1 to n-1 do begin
  | | Следующий [i] := i+1;
  | end;
  | Свободная:=1;
  end;

  function  Есть_место: boolean;
  begin
  | Есть Место := (Свободная <> 0);
  end;

  procedure Добавить (t: T; s: integer);
  | {Добавить t к s-му стеку}
  | var i: 1..n;
  begin
  | {Есть_место}
  | i := Свободная;
  | Свободная := Следующий [i];
  | Вершина [s] :=i;
  | Содержание [i] := t;
  | Следующий [i] := Вершина [s];
  end;

  function Пуст (s: integer): boolean; {s-ый стек пуст}
  begin
  | Пуст := (Вершина [s] = 0);
  end;

  procedure Взять (var t: T; s: integer);
  | {взять из s-го стека в t}
  | var i: 1..n;
  | begin
  | {not Пуст (s)}
  | i := Вершина [s];
  | t := Содержание [i];
  | Вершина [s] := Следующий [i];
  | Следующий [i] := Свободная;
  | Свободная := i;
  end;

     6.2. Очереди.

     Значениями типа "очередь элементов типа T", как и для  сте-
ков, являются последовательности значений типа T. Разница состо-
ит  в том, что берутся элементы не с конца, а с начала (а добав-
ляются по-прежнему в конец).

     Операции с очередями.

        Сделать_пустой (var x: очередь элементов типа T);
        Добавить (t: T, var x: очередь элементов типа T);
        Взять (var t: T, var x: очередь элементов типа T);
        Пуста (x: очередь элементов типа T): boolean;
        Очередной (x: очередь элементов типа T): T.

     При выполнении команды "Добавить" указанный элемент  добав-
ляется  в  конец  очереди.  Команда "Взять" выполнима, лишь если
очередь непуста, и  забирает  из  нее  первый  (положенный  туда
раньше  всех)  элемент, помещая его в t. Значением функции "Оче-
редной" (определенной для непустой очереди) является первый эле-
мент очереди.
     Английские названия стеков - Last In First  Out  (последним
вошел  -  первым вышел), а очередей - First In First Out (первым
вошел - первым вышел).

     Реализация очередей в массиве.

     6.2.1. Реализовать операции с очередью  ограниченной  длины
так,  чтобы количество действий для каждой операции было ограни-
чено константой, не зависящей от длины очереди.

     Решение. Будем хранить элементы очереди в соседних  элемен-
тах  массива.  Тогда  очередь  будет прирастать справа и убывать
слева. Поскольку при этом она может дойти до края, свернем  мас-
сив в окружность.
     Введем массив Содержание: array [0..n-1] of T и переменные
         Первый: 0..n-1,
         Длина : 0..n.
При этом элементами очереди будут
         Содержание [Первый], Содержание [Первый + 1],...,
                   Содержание [Первый + Длина - 1],
где  сложение рассматривается по модулю n. (Предупреждение. Если
вместо этого ввести переменные Первый и  Последний,  принимающие
значения  в  вычетах  по  модулю n, то пустая очередь может быть
спутана с очередью из n элементов.)

     Моделирование операций:

     Сделать Пустой:
        Длина := 0;
        Первый := 0;

     Добавить элемент:
        {Длина < n}
        Содержание [(Первый + Длина) mod n] := элемент;
        Длина := Длина + 1;

     Взять элемент;
        {Длина > 0}
        элемент := Содержание [Первый];
        Первый := (Первый + 1) mod n;
        Длина := Длина - 1;

     Пуста = (Длина = 0);

     Очередной = Содержание [Первый];

     6.2.2.  (Сообщил А.Г.Кушниренко) Придумать способ моделиро-
вания очереди с помощью двух стеков (и фиксированного числа  пе-
ременных  типа T). При этом отработка n операций с очередью (на-
чатых, когда очередь была  пуста)  должна  требовать  порядка  n
действий.

     Решение.  Инвариант:  стеки, составленные концами, образуют
очередь. (Перечисляя элементы одного стека вглубь и  затем  эле-
менты  второго  наружу,  мы  перечисляем все элементы очереди от
первого до последнего.) Ясно, что добавление сводится к добавле-
нию к одному из стеков, а проверка пустоты - к проверке  пустоты
обоих стеков. Если мы хотим взять элемент, есть два случая. Если
стек,  где  находится  начало очереди, не пуст, то берем из него
элемент. Если он пуст, то предварительно переписываем в него все
элементы второго стека, меняя порядок (это происходит  само  при
перекладывании  из стека в стек) и сводим дело к первому случаю.
Хотя число действий при этом и не ограничено константой, но тре-
бование задачи выполнено, так как каждый элемент  очереди  может
участвовать в этом процессе не более одного раза.

     6.2.3. Деком называют структуру, сочетающую очередь и стек:
класть и забирать элементы можно с обоих концов. Как реализовать
дек ограниченного размера на базе массива так, чтобы каждая опе-
рация требовала ограниченного числа действий?

     6.2.4. (Сообщил А.Г.Кушниренко.) Имеется дек элементов типа
T  и конечное число переменных типа T и целого типа. В начальном
состоянии в деке некоторое число элементов. Составить программу,
после исполнения которой в деке остались бы те же самые  элемен-
ты, а их число было бы в одной из целых переменных.

     Указание.  (1) Элементы дека можно циклически переставлять,
забирая с одного конца и помещая в другой. После  этого,  сделав
столько  же  шагов  в обратном направлении, можно вернуть все на
место. (2) Как понять, прошли мы полный круг или не прошли? Если
бы был какой-то элемент, заведомо отсутствующий в деке, то можно
было бы его подсунуть и ждать  вторичного  появления.  Но  таких
элементов нет. Вместо этого можно для данного n выполнить цикли-
ческий  сдвиг  на  n дважды, подсунув разные элементы, и посмот-
реть, появятся ли разные элементы через n шагов.

     Применение очередей.

     6.2.5. Напечатать в  порядке  возрастания  первые  n  нату-
ральных  чисел, в разложение которых на простые множители входят
только числа 2, 3, 5.

       Решение. Введем три очереди x2, x3, x5, в  которых  будем
хранить элементы, которые в 2 (3, 5) раз больше напечатанных, но
еще не напечатанные. Определим процедуру

        procedure напечатать_и_добавить (t: integer);
        begin
        | writeln (t);
        | добавить (2*t, x2);
        | добавить (3*t, x3);
        | добавить (5*t, x5);
        end;

Вот схема программы:

  напечатать_и_добавить (1);
  k := 1; { k - число напечатанных }
  {инвариант:  напечатано  в  порядке  возрастания k минимальных
  членов нужного множества; в очередях элементы, вдвое, втрое  и
  впятеро  большие напечатанных, но не напечатанные, расположен-
  ные в возрастающем порядке}
  while k <> n do begin
  | x := min (очередной (x2), очередной (x3), очередной (x5));
  | напечатать_и_добавить (x);
  | k := k+1;
  | ...взять x из тех очередей, где он был очередным;
  end;

     Пусть инвариант выполняется. Рассмотрим наименьший из нена-
печатанных элементов множества. Тогда он делится нацело на  одно
из чисел 2, 3, 5, и частное также принадлежит множеству. Значит,
оно  напечатано. Значит, x находится в одной из очередей и, сле-
довательно, является в ней первым (меньшие напечатаны, а элемен-
ты очередей не напечатаны). Напечатав x, мы должны его изъять  и
добавить его кратные.
     Длины очередей не превосходят числа напечатанных элементов.

     Следующая задача связана с графами (к которым мы вернёмся в
главе 9).

     Пусть задано конечное множество, элементы которого называют
вершинами, а также некоторое множество упорядоченных пар вершин,
называемых  ребрами. В этом случае говорят, что задан ориентиро-
ванный граф. Пару <p, q> называют ребром с началом p и концом q;
говорят также, что оно выходит из вершины p и входит  в  вершину
q. Обычно вершины графа изображают точками, а ребра - стрелками,
ведущими  из  начала  в конец. (В соответствии с определением из
данной вершины в данную ведет не более  одного  ребра;  возможны
ребра, у которых начало совпадает с концом.)

     6.2.6.  Известно, что ориентированный граф связен, т. е. из
любой вершины можно пройти в любую по  ребрам.  Кроме  того,  из
каждой  вершины  выходит столько же ребер, сколько входит. Дока-
зать, что существует замкнутый цикл, проходящий по каждому ребру
ровно один раз. Составить алгоритм отыскания такого цикла.

     Решение. Змеей будем называть непустую очередь из вершин, в
которой любые две вершины соединены ребром графа (началом  явля-
ется  та вершина, которая ближе к началу очереди). Стоящая в на-
чале очереди вершина будет хвостом змеи, последняя - головой. На
рисунке змея изобразится в виде цепи ребер графа, стрелки  ведут
от  хвоста  к голове. Добавление вершины в очередь соответствует
росту змеи с головы, взятие вершины - отрезанию кончика хвоста.
     Вначале змея состоит из единственной вершины. Далее мы сле-
дуем такому правилу:

while змея включает не все ребра do begin
| if из головы выходит неиспользованное в змее ребро then begin
| | удлинить змею этим ребром
| end else begin
| | {хвост змеи в той же вершине, что и голова}
| | отрезать конец хвоста и добавить его к голове
| | {"змея откусывает конец хвоста"}
| end;
end;

     Докажем, что мы достигнем цели.

     1)  Идя по змее от хвоста к голове, мы входим в каждую вер-
шину столько же раз, сколько выходим. Так как  в  любую  вершину
входит столько же ребер, сколько выходит, то невозможность выйти
означает, что мы начали движение в этой же точке.
     2) Змея не укорачивается, поэтому либо она  охватывает  все
ребра,  либо, начиная с некоторого момента, будет иметь постоян-
ную длину. Во втором случае змея будет бесконечно "скользить  по
себе".  Это возможно, только если из всех вершин змеи не выходит
неиспользованных ребер. Из связности следует,  что  использованы
все ребра.

     Замечание  по  реализации на паскале. Вершинами графа будем
считать числа 1..n. Для каждой вершины  i  будем  хранить  число
Out[i]  выходящих  из  нее  ребер, а также номера Num[i][1],...,
Num[i][Out[i]] тех вершин, куда  эти  ребра  ведут.  В  процессе
построения  змеи  будет  выбирать  первое свободное ребро. Тогда
достаточно будет хранить для каждой вершины число  выходящих  из
нее  использованных  ребер  -  это  будут ребра, идущие в начале
списка.

     6.2.7. Доказать, что для всякого  n  существует  последова-
тельность  нулей  и  единиц  длины  (2 в степени n) со следующим
свойством: если "свернуть ее в кольцо" и рассмотреть  все  фраг-
менты  длины  n  (их число равно (2 в степени n)), то мы получим
все возможные последовательности нулей и единиц длины n. Постро-
ить алгоритм отыскания такой  последовательности,  требующий  не
более (C в степени n) действий для некоторой константы C.

     Указание. Рассмотрим граф, вершинами которого являются пос-
ледовательности  нулей  и единиц длины (n-1). Будем считать, что
из вершины x ведет ребро в вершину y, если x может быть началом,
а y - концом некоторой последовательности длины n. Тогда из каж-
дой вершины входит и выходит два ребра. Цикл, проходящий по всем
ребрам, и даст требуемую последовательность.

     6.2.8. Реализовать k очередей с ограниченной суммарной дли-
ной  n,  используя  память  порядка  n+k, причем каждая операция
(кроме начальной, делающей все очереди пустыми) должна требовать
ограниченного константой числа действий.

     Решение.  Действуем аналогично ссылочной реализации стеков:
мы помним (для каждой очереди) первого, каждый член очереди пом-
нит следующего за ним (для последнего считается, что за ним сто-
ит фиктивный элемент с номером 0). Кроме  того,  мы  должны  для
каждой  очереди  знать  последнего  (если  он  есть)  - иначе не
удастся добавлять. Как и для стеков, отдельно есть цепь  свобод-
ных  ячеек. Заметим, что для пустой очереди информация о послед-
нем элементе теряет смысл - но она и не используется при  добав-
лении.

        Содержание: array [1..n] of T;
        Следующий: array [1..n] of 0..n;
        Первый: array [1..n] of 0..n;
        Последний: array [1..k] of 0..n;
        Свободная : 0..n;

  procedure Сделать_пустым;
  | var i: integer;
  begin
  | for i := 1 to n-1 do begin
  | | Следующий [i] := i + 1;
  | end;
  | Свободная := 1;
  | for i := 1 to k do begin
  | | Первый [i]:=0;
  | end;
  end;

  function Есть_место : boolean;
  begin
  | Есть_место := Свободная <> 0;
  end;

  function Пуста (номер_очереди: integer): boolean;
  begin
  | Пуста := Первый [номер_очереди] = 0;
  end;

  procedure Взять (var t: T; номер_очереди: integer);
  | var перв: integer;
  begin
  | {not Пуста (номер_очереди)}
  | перв := Первый [номер_очереди];
  | t := Содержание [перв]
  | Первый [номер_очереди] := Следующий [перв];
  | Следующий [перв] := Свободная;
  | Свободная := Перв;
  end;

  procedure Добавить (t: T; номер_очереди: integer);
  | var нов, посл: 1..n;
  begin
  | {Есть_свободное_место }
  | нов := Свободная; Свободная := Следующий [Свободная];
  | {из списка свободного места изъят номер нов}
  | if Пуста (номер_очереди) then begin
  | | Первый [номер_очереди] := нов;
  | | Последний [номер_очереди] := нов;
  | | Следующий [нов] := 0;
  | | Содержание [нов] := t;
  | end else begin
  | | посл := Последний [номер_очереди];
  | | {Следующий [посл] = 0 }
  | | Следующий [посл] := нов;
  | | Следующий [нов] := 0;
  | | Содержание [нов] := t
  | | Последний [номер_очереди] := нов;
  | end;
  end;

  function Очередной (номер_очереди: integer): T;
  begin
  | Очередной := Содержание [Первый [номер_очереди]];
  end;

     6.2.9. Та же задача для деков вместо очередей.

     Указание. Дек - структура симметричная, поэтому  надо  хра-
нить  ссылки  в  обе стороны (вперед и назад). При этом удобно к
каждому деку добавить фиктивный элемент, замкнув его в кольцо, и
точно такое же кольцо образовать из свободных позиций.

     В следующей задаче дек используется для хранения вершин вы-
пуклого многоугольника.

     6.2.10.  На плоскости задано n точек, пронумерованных слева
направо (а при равных абсциссах - снизу вверх). Составить  прог-
рамму, которая строит многоугольник, являющийся их выпуклой обо-
лочкой, за не более чем C*n действий.

     Решение. Будем присоединять точки к выпуклой оболочке  одна
за  другой.  Легко  показать, что последняя присоединенная точка
будет одной из вершин выпуклой оболочки. Эту  вершину  мы  будем
называть выделенной. Очередная присоединяемая точка видна из вы-
деленной  (почему?). Дополним наш многоугольник, выпустив из вы-
деленной вершины "иглу", ведущую в присоединяемую  точку.  Полу-
чится  вырожденный многоугольник, и остается ликвидировать в нем
"впуклости".

                                               [Рисунок]

     Будем хранить вершины многоугольника в деке в порядке обхо-
да его периметра по часовой стрелке. При этом выделенная вершина
является началом и концом (головой и хвостом) дека.  Присоедине-
ние  "иглы" теперь состоит в добавлении присоединяемой вершины в
голову и в хвост дека.  Устранение  впуклостей  несколько  более
сложно.  Назовем  подхвостом и подподхвостом элементы дека, сто-
ящие за его хвостом. Устранение впуклости у хвоста делается так:

    while по дороге из хвоста в подподхвост  мы поворачиваем
    |                  у подхвоста влево ("впуклость") do begin
    | выкинуть подхвост из дека
    end

Таким же способом устраняется впуклость у головы дека.

    Замечание. Действия с подхвостом и подподхвостом не входят в
определение дека, однако сводятся к небольшому числу манипуляций
с деком (надо забрать три элемента с хвоста, сделать что надо  и
вернуть).

    Ещё одно замечание. Есть два вырожденных случая: если мы во-
обще не поворачиваем у похвоста (т.е. три соседние вершины лежат
на одной прямой) и если мы поворачиваем на 180 градусов (так бы-
вает,  если наш многоугольник есть двуугольник). В первом случае
подхвост стоит удалить (чтобы в выпуклой оболочке не было лишних
вершин), а во втором случае - обязательно оставить.

     6.3. Множества.

     Пусть  Т - некоторый тип. Существует много способов хранить
(конечные) множества элементов типа Т; выбор между ними  опреде-
ляется типом T и набором требуемых операций.

     Подмножества множества {1..n}.

     6.3.1.  Используя  память,  пропорциональную   n,   хранить
подмножества множества {1..n}.

          Операции              Число действий

        Сделать пустым                C*n
        Проверить принадлежность      C
        Добавить                      C
        Удалить                       С
        Минимальный элемент           C*n
        Проверка пустоты              C*n

     Решение. Храним множество как array [1..n] of boolean.

     6.3.2.  То  же,  но  проверка пустоты должна выполняться за
время C.

       Решение. Храним дополнительно количество элементов.

     6.3.3. То же при следующих ограничениях на число действий:

          Операции             Число действий

        Сделать пустым                C*n
        Проверить принадлежность      C
        Добавить                      C
        Удалить                       C*n
        Минимальный элемент           C
        Проверка пустоты              C

     Решение.  Дополнительно  храним  минимальный  элемент  мно-
жества.

     6.3.4 То же при следующих ограничениях на число действий:

          Операции             Число действий

        Сделать пустым                С*n
        Проверить принадлежность      С
        Добавить                      С*n
        Удалить                       С
        Минимальный элемент           С
        Проверка пустоты              C

       Решение.  Храним минимальный, а для каждого - следующий и
предыдущий по величине.

     Множества целых чисел.

     В следующих задачах величина элементов множества не ограни-
чена, но их количество не превосходит n.

     6.3.5. Память C*n.

          Операции             Число действий

        Сделать пустым                C
        Число элементов               C
        Проверить принадлежность      C*n
        Добавить новый
         (заведомо отсутствующий)     C
        Удалить                       C*n
        Минимальный элемент           C*n
        Взять какой-то элемент        C

     Решение.   Множество   представляем  с  помощью  переменных
a:array [1..n] of integer, k: 0..n; множество содержит k элемен-
тов a[1],...,a[k]; все они различны. По существу мы храним  эле-
менты множества в стеке (без повторений).

     6.3.6. Память C*n.

          Операции             Число действий

        Сделать пустым                C
        Проверить пустоту             C
        Проверить принадлежность      C*(log n)
        Добавить                      С*n
        Удалить                       C*n
        Минимальный элемент           С

     Решение. См. решение предыдущей задачи с дополнительным ус-
ловием a[1] < ... < a[k]. При проверке принадлежности используем
двоичный поиск.

     В следующей задаче полезно комбинировать разные способы.

     6.3.7.  Используя описанное в предыдущей задаче представле-
ние множеств, найти все вершины ориентированного графа,  доступ-
ные  из  данной по ребрам. (Вершины считаем числами 1..n.) Время
не больше C * (общее число ребер, выходящих  из  доступных  вер-
шин).

     Решение.  (Другое решение смотри в главе о рекурсии.) Пусть
num[i]  -  число  ребер,  выходящих  из   i,   out[i][1],   ...,
out[i][num[i]] - вершины, куда ведут ребра.

  procedure Доступные (i: integer);
  |   {напечатать все вершины, доступные из i, включая i}
  | var  X: подмножество 1..n;
  |      P: подмножество 1..n;
  |      q, v, w: 1..n;
  |      k: integer;
  begin
  | ...сделать X, P пустыми;
  | writeln (i);
  | ...добавить i к X, P;
  | {(1) P = множество напечатанных вершин; P содержит i;
  |  (2) напечатаны только доступные из i вершины;
  |  (3) X - подмножество P;
  |  (4) все напечатанные вершины, из которых выходит
  |      ребро в ненапечатанную вершину, принадлежат X}
  | while X непусто do begin
  | | ...взять какой-нибудь элемент X в v;
  | | for k := 1 to num [v] do begin
  | | | w := out [v][k];
  | | | if w не принадлежит P then begin
  | | | | writeln (w);
  | | | | добавить w в P;
  | | | | добавить w в X
  | | | end;
  | | end;
  | end;
  end;

     Свойство (1) не нарушается, так как печать  происходит  од-
новременно с добавлением в P. Свойства (2): раз v было в X, то v
доступно,  поэтому  w  доступно. Свойство (3) очевидно. Свойство
(4): мы удалили из X элемент v, но все вершины, куда из  v  идут
ребра, перед этим напечатаны.

     Оценка  времени  работы. Заметим, что изъятые из X элементы
больше туда не добавляются, так как они  в  момент  изъятия  (и,
следовательно, всегда позже) принадлежат P, а добавляются только
элементы  не  из P. Поэтому цикл while выполняется не более, чем
по разу, для всех  доступных  вершин,  а  цикл  for  выполняется
столько раз, сколько из вершины выходит ребер.
     Для  X  надо  использовать представление со стеком или оче-
редью (см. выше), для P - булевский массив.

     6.3.8. Решить предыдущую задачу, если требуется, чтобы дос-
тупные вершины печатались в таком порядке: сначала заданная вер-
шина, потом ее соседи, потом соседи соседей (еще  не  напечатан-
ные) и т.д.

     Указание. Так получится, если использовать очередь в приве-
денном выше решении: докажите индукцией по k, что существует мо-
мент, в который напечатаны все вершины на расстоянии  не  больше
k, а в очереди находятся все вершины, удаленные ровно на k.

Более  сложные  способы представления множеств будут разобраны в
главах 11 (Хеширование) и 12 (Деревья).

     6.4. Разные задачи.

     6.4.1. Реализовать структуру данных, которая имеет  все  те
же операции, что массив длины n, а именно

        начать работу
        положить в i-ю ячейку число n
        узнать, что лежит в i-ой ячейке

а также операцию "указать номер минимального элемента" (или  од-
ного  из  минимальных  элементов).  Количество действий для всех
операций  должно  быть не более C*log n, не считая операции "на-
чать работу" (которая требует не более C*n действий).

     Решение. Используется прием, изложенный в разделе о  сорти-
ровке  деревом. Именно, надстроим над элементами массива как над
листьями двоичное дерево, в каждой вершине которого храним мини-
мум элементов соответствующего поддерева. Корректировка этой ин-
формации, а также прослеживание пути  из  корня  к  минимальному
элементу требуют логарифмического числа действий.

     6.4.2.  Приоритетная очередь - это очередь, в которой важно
не то, кто встал последним (порядок помещения в  нее  не  играет
роли),  а кто главнее. Более точно, при помещении в очередь ука-
зывается приоритет помещаемого объекта (будем считать приоритеты
целыми числами), а при взятии из очереди  выбирается  элемент  с
наибольшим  приоритетом  (или один из таких элементов). Реализо-
вать приоритетную очередь так, чтобы помещение и взятие элемента
требовали логарифмического числа действий (от размера очереди).

     Решение. Следуя алгоритму сортировки деревом (в его оконча-
тельном  варианте),  будем  размещать элементы очереди в массиве
x[1]..x[k],  поддерживая  такое  свойство:  x[i]  старше  (имеет
больший  приоритет)  своих сыновей x[2i] и x[2i+1], если таковые
существуют - и, следовательно, всякий элемент старше  своих  по-
томков. (Сведения о приоритета также хранятся в массиве, так что
мы  имеем  дело  с  массивом пар (элемент, приоритет).) Удаление
элемента с сохранением этого свойства описано в алгоритме сорти-
ровки. Надо еще уметь восстанавливать свойство после  добавления
элемента в конец. Это делается так:

    t:= номер добавленного элемента
    {инвариант: в дереве любой предок приоритетнее потомка,
        если этот потомок - не t}
    while t - не корень и t старше своего отца do begin
    | поменять t с его отцом
    end;

Если  очередь образуют граждане, стоящие в вершинах дерева, т.е.
за каждым стоит двое, а перед каждым (кроме первого) - один,  то
смысл  этого алгоритма ясен: встав в конец, приоритетный гражда-
нин начинает пробираться к началу, вытесняя  впереди  стоящих  -
пока не встретит более приоритетного.

     Замечание. Приоритетную  очередь  естественно  использовать
при  моделировании  протекающих  во  времени процессов. При этом
элементы очереди - это ожидаемые события, а их приоритет опреде-
ляется временем, когда они произойдут.